メールオーガナイザーを導入する - 50歳手前の糖尿病メタボおっちゃんの色々悪あがき日記

流れ

メールオーガナイザーを導入いたします。今回は簡単です。

①Outlookにスクリプトをカット＆ペーストする。

②仕分けルール「スクリプトを実行」をセットする。

①Outlookにスクリプトをカット＆ペーストする。

1)OutLookのメニュー＜開発＞→「Visual Basic」を選択します。

f:id:edger_arkw:20200705055033p:plain — VBエディタを起動する

2)VBAエディタが起動します。画面中央の空の部分に以下のコードをカット＆ペーストします。

Sub MailOrganizer(Item As Outlook.MailItem)
    Const MAIL_ADR = "n-yamamoto@pola.co.jp"
    Const FNAME = "山田　太郎"
    Const LNAME = "山田"
    Const TOMAX = 3
    Const LINES = 3
   
    '自分が送信者の場合は終了
    If Item.SenderEmailAddress = MAIL_ADR Then
        Exit Sub
    End If
   
    Dim Sw_STAR
    Sw_STAR = False
   
    Dim Toz, SwMailAdr, Ix
    Toz = Split(Item.To, ";")        '宛先
   
    ' 宛先が指定人数名以内に自分のメールアドレス（社外メール用）
    If UBound(Toz) < TOMAX And InStr(Item.To, MAIL_ADR) > 0 Then
        Sw_STAR = True
    End If
    ' 宛先が指定人数以内に自分の名字・名前（社内メール用）
    If UBound(Toz) < TOMAX And InStr(Item.To, FNAME) > 0 Then
        Sw_STAR = True
    End If
   
    '本文の上部指定行に自分の名前がある。
    Dim Bodyz, strBody
    If Item.Body <> "" Then '本文あり
        Bodyz = Split(Item.Body, vbCrLf) '本文
        strBody = ""
        For Ix = 0 To LINES
            If Ix > UBound(Bodyz) Then
                Exit For
            End If
            strBody = strBody & Bodyz(Ix)
        Next
        If InStr(strBody, LNAME) > 0 Then
            Sw_STAR = True
        End If
    End If
   
    If Sw_STAR = False Then
        Exit Sub
    End If
    '
    '期限切れフラグで赤く目立つようにする
    Item.FlagStatus = olFlagMarked
    Item.FlagRequest = "あなた宛のメールです"
    Item.FlagDueBy = DateAdd("d", -1, Now) '期限を昨日にし、あえて期限切れ
    Item.Save
End Sub

3)赤字部分を修正します。

Sub MailOrganizer(Item As Outlook.MailItem)
    Const MAIL_ADR = "Taro-yam@xxxxxxxx.co.jp"
    Const FNAME = "山田　太郎"
    Const LNAME = "山田"
    Const TOMAX = 3
    Const LINES = 3

　MAIL_ADRは、自分のメールアドレスを記述します。社外メールの宛名に自分がいるかの判定に利用します。

　FNAMEは「名字＋（全角空白）＋名前」を記述します。社内メールの宛名に自分があるかの判定に利用します。

　LNAMEは「名字」を記述します。本文の先頭指定行内に自分がいるかの判定に利用します。

　TOMAXは、少人数宛メールの検知に使用します。指定人数以内のTO宛先に自分がいいた場合、赤くします。推奨値は「3」です。この機能を利用したくない場合は「0」を指定します。

　LINESは、本文先頭何行目までに、自分の名字が書いてある場合、赤くします。ステ証値は「3」です。この機能を利用したくない場合は「0」を指定します。

3)左上の保存アイコンを押して保存します。VBAエディタを終了してください。